multmpec.gms : Educational bilevel model with VI followers

Description

This model demonstrate how to use EMP for a bilevel model with multiple
inner variational inequality followers.

The actual model to solve is:

min_{u,v,w,z}   z
  s.t.   exp(z) + w = 2, z >= 1

         (u,v) solves VI( [v+w+z-1; u-log(v)], {(u,v) | u >= 0, v >= 0 } )

            w  solves VI(               w+z+3, {   w  |         w free } )

Note that the two VI's (due to the definitional sets) correspond respectively
to a complementarity problem:

       0 <= u  perpendicular to  v + w + z - 1 >= 0
       0 <= v  perpendicular to  u - log(v) >= 0

and a linear equation:

      w + z + 3 = 0

The starting value for v is needed to protect the evaluation of log(v).

Contributor: Michael Ferris and Jan-H. Jagla, December 2009


Small Model of Type : BP


Category : GAMS EMP library


Main file : multmpec.gms

$title Educational bilevel model with VI followers (MULTMPEC,SEQ=25)

$ontext

This model demonstrate how to use EMP for a bilevel model with multiple
inner variational inequality followers.

The actual model to solve is:

min_{u,v,w,z}   z
  s.t.   exp(z) + w = 2, z >= 1

         (u,v) solves VI( [v+w+z-1; u-log(v)], {(u,v) | u >= 0, v >= 0 } )

            w  solves VI(               w+z+3, {   w  |         w free } )

Note that the two VI's (due to the definitional sets) correspond respectively
to a complementarity problem:

       0 <= u  perpendicular to  v + w + z - 1 >= 0
       0 <= v  perpendicular to  u - log(v) >= 0

and a linear equation:

      w + z + 3 = 0

The starting value for v is needed to protect the evaluation of log(v).

Contributor: Michael Ferris and Jan-H. Jagla, December 2009

$offtext

positive variable u;
variables v, w, z;
equations f1, f2, f3, h;

f1.. v + w + z =n= 1;
f2.. u =n= log(v);

f3.. w + z =n= -3;

h.. exp(z) + w =e= 2;

v.lo = 0;
v.l  = 1;
z.lo = 1;

model mpec /all/;

$onecho > %emp.info%
bilevel
 vi f1 u
    f2 v
 vi f3 w
$offecho

solve mpec using emp min z;