# tblGamsSource

largetext:
$Title  A Transportation Problem (TRNSPORT,SEQ=1)
$Ontext

This problem finds a least cost shipping schedule that meets
requirements at markets and supplies at factories.


Dantzig, G B, Chapter 3.3. In Linear Programming and Extensions.
Princeton University Press, Princeton, New Jersey, 1963.

This formulation is described in detail in:
Rosenthal, R E, Chapter 2: A GAMS Tutorial. In GAMS: A User's Guide.
The Scientific Press, Redwood City, California, 1988.

The line numbers will not match those in the book because of these
comments.

$Offtext


* Data section
  Sets
       i   canning plants
       j   markets;

  Parameters
       a(i)  capacity of plant i in cases
       b(j)  demand at market j in cases;

  Parameter d(i,j) distance in thousands of miles;

  Scalar f  freight in dollars per case per thousand miles;

  Parameter c(i,j)  transport cost in thousands of dollars per case ;

  Variables
       x(i,j)  shipment quantities in cases
       z       total transportation costs in thousands of dollars ;

  Positive Variable x ;


* Load data
$gdxin %datainput%
$load i j
$loaddc a b d f
$gdxin


* Mathematical model

  c(I,j) = f * d(I,j) / 1000 ;

  Equations
       cost        define objective function
       supply(i)   observe supply limit at plant I
       demand(j)   satisfy demand at market j ;

  cost ..        Z  =e=  sum((I,j), c(I,j)*x(I,j)) ;

  supply(i) ..   Sum(j, x(I,j))  =l=  a(i) ;

  demand(j) ..   Sum(I, x(I,j))  =g=  b(j) ;

  Model transport /all/ ;

  Solve transport using lp minimizing z ;

  Display x.l, x.m;


*Solution reporting
execute_unload '%dataoutput%',x,z,c;


