Reference

Neculai Andrei, Nonlinear Optimization Applications Using the GAMS Technology,Springer Optimization and Its Applications, Model CpaR (4.4) in chapter Nonlinear Systems of Equations , 2013

Mainfile : cpar.gms

$onText
Combustion of propan in air, reduced formulation. The unknowns represent the
number of moles of a given product formed for each mole of propane.

The reduced formulation is taken from Meintjes, K. and Morgan, A.P.,
Chemical equilibrium systems as numerical test problems. ACM Trans. Math.
Software, 16, 1990, pp. 143-151.

Please see:
Neculai Andrei, "Models, Test Problems and Applications for
Mathematical Programming". Technical Press, Bucharest, 2003.
Application U86, page 67. Application A23, page 376.
$offText

Scalars R5  /0.193/
        R6  /0.4106217541e-3/
        R7  /0.5451766686e-3/
        R8  /0.44975e-6/
        R9  /0.3407354178e-4/
        R10 /0.9615e-6/
        R   /10/;

Variables x1,x2,x3,x4,x5, obj;
Equations e1,e2,e3,e4,e5, e;

e1.. x1*x2+x1-3*x5 =e= 0;
e2.. 2*x1*x2+x1+2*R10*POWER(x2,2)+x2*POWER(x3,2)+R7*x2*x3+
     R9*x2*x4+R8*x2-R*x5 =e= 0;
e3.. 2*x2*POWER(x3,2)+R7*x2*x3+2*R5*POWER(x3,2)+R6*x3-8*x5 =e= 0;
e4.. R9*x2*x4+2*POWER(x4,2)-4*R*x5 =e= 0;
e5.. x1*x2+x1+R10*POWER(x2,2)+x2*POWER(x3,2)+R7*x2*x3+R9*x2*x4+R8*x2+
     R5*POWER(x3,2)+R6*x3+POWER(x4,2)-1 =e= 0;

e..  obj =e= 1;

* Bounds on variables
x1.lo = 0.0001;
x1.up = 100;
x2.lo = 0.0001;
x2.up = 100;
x3.lo = 0.0001;
x3.up = 100;
x4.lo = 0.0001;
x4.up = 100;
x5.lo = 0.0001;
x5.up = 100;

* Initial point
x1.l = 10;
x2.l = 10;
x3.l = 0.05;
x4.l = 50.5;
x5.l = 0.05;

Model cpaR /all/;

Solve cpaR using nlp minimizing obj;
* End cpaR