Reference

Neculai Andrei, Nonlinear Optimization Applications Using the GAMS Technology,Springer Optimization and Its Applications, Model Netreactor (7.5) in chapter Applications in Chemical Engineering , 2013

$onText
The reactor network design problem.

Ryoo, H.S., Sahinidis, N.V., Global optimization of nonconvex NLPs and
MINLPs with applications in process design. Comput. Chem. Eng., 19, 1995,
pp.551-566.

Floudas, C.A., Pardalos, P.M., et al. Handbook of Test Problems in Local
and Global Optimization. Kluwer Academic Publishers, Dordrecht, 1999,
Section 8.2.8, Test problem 8, pp. 113-114.
$offText

Scalars  k1 /0.09755988/
         k2 /0.09658428/
         k3 /0.0391908 /
         k4 /0.9/;

Variables ca1, ca2, cb1, cb2, v1, v2, obj;

Equations e1, e2, e3, e4, e5, e;

e1.. ca1 + k1*ca1*v1 =e= 1;

e2.. ca2 - ca1 + k2*ca2*v2 =e= 0;

e3.. cb1 + ca1 + k3*cb1*v1 =e= 1;

e4.. cb2 - cb1 + ca2 - ca1 + k4*cb2*v2 =e= 0;

e5.. sqrt(v1) + sqrt(v2) =l= 4;

e..  obj =e= -cb2;

* Bounds on variables
ca1.lo = 0;
ca1.up = 1;
ca2.lo = 0;
ca2.up = 1;
cb1.lo = 0;
cb1.up = 1;
cb2.lo = 0;
cb2.up = 1;
v1.lo = 0.00001;
v1.up = 16;
v2.lo = 5.00001;
v2.up = 16;

*Initial point
ca1.l = 1;
ca2.l = 1;
cb1.l = 1;
cb2.l = 1;
v1.l = 1;
v2.l = 1;

Model netreactor /all/;

Solve netreactor minimizing obj using nlp;
* End netreactor