Reference

Neculai Andrei, Nonlinear Optimization Applications Using the GAMS Technology,Springer Optimization and Its Applications, Model Trafo (6.1) in chapter Applications in Electrical Engineering , 2013

Mainfile : trafo.gms

$onText
Transformer design

Application A1. pp.344.
Andrei, N., Models, Test Problems and Applications of Mathematical
Programming. Technical Press, Bucharest, 2003.

Please see also: Problem 93. pp. 108.
Hock - Schittkowski, Test Examples for Nonlinear Programming Codes.
Springer Verlag, New York, 1981
$offText

* The variables x1,x2,x3 and x4 are physical dimensions of transformer
* parts, x5 and x6 are the magnetic flux density and current density
* respectively.

VARIABLES
         x1, x2, x3, x4, x5, x6,
         objval    objective function variable;

FREE VARIABLES    objval;

EQUATIONS
         f     Objective function
         g1
         g2;

f  .. objval =e=0.0204*x1*x4*(x1+x2+x3)+0.0187*x2*x3*(x1+1.57*x2+x4)+
                0.0607*x1*x4*POWER(x5,2)*(x1+x2+x3)+
                0.0437*x2*x3*POWER(x6,2)*(x1+1.57*x2+x4);

g1  .. 0.001*x1*x2*x3*x4*x5*x6 =g= 2.07;
g2  .. -0.00062*x1*x4*POWER(x5,2)*(x1+x2+x3)-
       0.00058*x2*x3*POWER(x6,2)*(x1+1.57*x2+x4) =g= -1;

* Bounds on variables:
x1.LO = 0;
x2.LO = 0;
x3.LO = 0;
x4.LO = 0;
x5.LO = 0;
x6.LO = 0;

* Initial point:
x1.L=5.4;
x2.L=4.4;
x3.L=11.02;
x4.L=11.82;
x5.L=0.702;
x6.L=0.852;

MODEL trafo /ALL/;

SOLVE trafo USING NLP MINIMIZING objval;

$ifThenI x%mode%==xbook
file out /traf.dat/
put out;
put x1.l:15:7,  x2.l:15:7,  x3.l:15:7,  x4.l:15:7, x5.l:15:7, x6.l:15:7  /;
put objval.l:15:7 /;
$endIf
* End trafo