Description

Hideo Hashimoto, Kojun Hamada, and Nobuhiro Hosoe, "A Numerical Approach
to the Contract Theory: the Case of Adverse Selection", GRIPS Discussion
Paper 11-27, National Graduate Institute for Policy Studies, Tokyo, Japan,
March 2012.

Keywords: nonlinear programming, contract theory, principal-agent problem,
          adverse selection, parts supply problem

Small Model of Type : NLP

Category : GAMS Model library

Main file : ps2_f.gms

$title Parts Supply Problem w/ 2 Types w/o Asymmetric Information (PS2_F,SEQ=359)

$onText
Hideo Hashimoto, Kojun Hamada, and Nobuhiro Hosoe, "A Numerical Approach
to the Contract Theory: the Case of Adverse Selection", GRIPS Discussion
Paper 11-27, National Graduate Institute for Policy Studies, Tokyo, Japan,
March 2012.

Keywords: nonlinear programming, contract theory, principal-agent problem,
          adverse selection, parts supply problem
$offText

option limCol = 0, limRow = 0;

Set i 'type of supplier' / eff, inf /;

Alias (i,j);

Parameter
   theta(i) 'efficiency'          / eff 0.2, inf 0.3 /
   p(i)     'probability of type' / eff 0.2, inf 0.8 /;

Scalar ru 'reservation utility' / 0 /;

* Definition of Primal/Dual Variables
Positive Variable
   x(i) "quality"
   b(i) "maker's revenue"
   w(i) "price";

Variable Util "maker's utility";

Equation
   obj    "maker's utility function"
   rev(i) "maker's revenue function"
   pc(i)  "participation constraint";

obj..    Util =e= sum(i, p(i)*(b(i) - w(i)));

rev(i).. b(i) =e= x(i)**(0.5);

pc(i)..  w(i) - theta(i)*x(i) =g= ru;

* Setting Lower Bounds on Variables to Avoid Division by Zero
x.lo(i) = 0.0001;

Model FB1 / all /;

solve FB1 maximizing Util using nlp;