Description

Small Model of Type : GAMS

Category : GAMS Test library

Main file : baron01.gms

$title 'BARON test suite - basic option reading test' (BARON01,SEQ=265)

  Sets
       i   canning plants   / seattle, san-diego /
       j   markets          / new-york, chicago, topeka / ;

  Parameters

       a(i)  capacity of plant i in cases
         /    seattle     350
              san-diego   600  /

       b(j)  demand at market j in cases
         /    new-york    325
              chicago     300
              topeka      275  / ;

  Table d(i,j)  distance in thousands of miles
                    new-york       chicago      topeka
      seattle          2.5           1.7          1.8
      san-diego        2.5           1.8          1.4  ;

  Scalar f  freight in dollars per case per thousand miles  /90/ ;

  Parameter c(i,j)  transport cost in thousands of dollars per case ;

            c(i,j) = f * d(i,j) / 1000 ;

  Variables
       x(i,j)  shipment quantities in cases
       z       total transportation costs in thousands of dollars ;

  Positive Variable x ;

  Equations
       cost        define objective function
       supply(i)   observe supply limit at plant i
       demand(j)   satisfy demand at market j ;

  cost ..        z  =e=  sum((i,j), c(i,j)*x(i,j)) ;

  supply(i) ..   sum(j, x(i,j))  =l=  a(i) ;

  demand(j) ..   sum(i, x(i,j))  =g=  b(j) ;

  Model transport /all/ ;
* x.up(i,j) = 260;
* x.up('seattle','chicago') = 250;
transport.optfile=1;

$onEcho > baron.opt
x.up = 260
x.up('seattle','chicago') = 250
$offEcho

option lp=baron;

Solve transport using lp minimizing z ;

abort$(abs(x.l('seattle','chicago')-250)>1e-5) 'wrong value should be 250';
abort$(abs(x.l('seattle','new-york')-85)>1e05) 'wrong value should be 85';

* Some tests that allowExternal/NLPSol/ExtNLPSolver work as advertised
$call mkdir c1 c2 k1 k2 e1
$set jjlog %system.dirsep%gmsjjlog.%gams.scrExt%
$onCheckErrorLevel
$call gamslib -q gear
$call gams gear minlp=baron lo=0 scrdir c1
$call grep -q "C O N O P T 3" c1%jjlog%
$echo NLPSol 6 > baron.op2
$call gams gear minlp=baron optfile=2 lo=0 scrdir c2
$call grep -q "C O N O P T 3" c2%jjlog%
$echo extNLPSolver knitro > baron.op2
$call gams gear minlp=baron optfile=2 lo=0 scrdir k1
$call grep -q "Artelys Knitro" k1%jjlog%
$echo NLPSol 6 >> baron.op2
$call gams gear minlp=baron optfile=2 lo=0 scrdir k2
$call grep -q "Artelys Knitro" k2%jjlog%
$echo AllowExternal 0 >> baron.op2
$call gams gear minlp=baron optfile=2 lo=0 scrdir e1
$call test "! -f e1%jjlog%"