Description

Contributor: Lutz Westermann

Small Model of Type : GAMS

Category : GAMS Test library

Main file : handle02.gms

$title 'Test handlecollect with save & restart' (HANDLE02,SEQ=335)

$onText

Contributor: Lutz Westermann
$offText

$onEcho > tmp1.gms

  Sets
       i   canning plants   / seattle, san-diego /
       j   markets          / new-york, chicago, topeka / ;

  Parameters

       a(i)  capacity of plant i in cases
         /    seattle     350
              san-diego   600  /

       b(j)  demand at market j in cases
         /    new-york    325
              chicago     300
              topeka      275  / ;

  Table d(i,j)  distance in thousands of miles
                    new-york       chicago      topeka
      seattle          2.5           1.7          1.8
      san-diego        2.5           1.8          1.4  ;

  Scalar f  freight in dollars per case per thousand miles  /90/ ;

  Parameter c(i,j)  transport cost in thousands of dollars per case ;

            c(i,j) = f * d(i,j) / 1000 ;

  Variables
       x(i,j)  shipment quantities in cases
       z       total transportation costs in thousands of dollars ;

  Positive Variable x ;

  Equations
       cost        define objective function
       supply(i)   observe supply limit at plant i
       demand(j)   satisfy demand at market j ;

  cost ..        z  =e=  sum((i,j), c(i,j)*x(i,j)) ;

  supply(i) ..   sum(j, x(i,j))  =l=  a(i) ;

  demand(j) ..   sum(i, x(i,j))  =g=  b(j) ;

  Model transport /all/ ;

scalar h;

transport.solvelink=%solveLink.asyncGrid%;

  Solve transport using lp minimizing z ;

h = transport.handle;

  Display x.l, x.m ;
$offEcho

$onEcho > tmp2.gms
while(handlecollect(h)=0,
   display$sleep(1) 'go to sleep';
   abort$(TimeElapsed > 5) 'waited too long' );
display x.l;
abort$handledelete(h) 'could not remove';
$offEcho

$call gams tmp1 s=1 lo=%gams.lo% gdir="%gams.scrdir%"
$if errorlevel 1 $abort tmp1 failed
$call gams tmp2 r=1 lo=%gams.lo% gdir="%gams.scrdir%"
$if errorlevel 1 $abort tmp2 failed