Description
Small Model of Type : GAMS
Main file : savep1.gms
$title execute_loadpoint: save point - clear - loadpoint - reoptimize (SAVEP1,SEQ=65)

  Sets
       i   canning plants   / seattle, san-diego /
       j   markets          / new-york, chicago, topeka / ;

  Parameters

       a(i)  capacity of plant i in cases
         /    seattle     350
              san-diego   600  /

       b(j)  demand at market j in cases
         /    new-york    325
              chicago     300
              topeka      275  / ;

  Table d(i,j)  distance in thousands of miles
                    new-york       chicago      topeka
      seattle          2.5           1.7          1.8
      san-diego        2.5           1.8          1.4  ;

  Scalar f  freight in dollars per case per thousand miles  /90/ ;

  Parameter c(i,j)  transport cost in thousands of dollars per case ;

            c(i,j) = f * d(i,j) / 1000 ;

  Variables
       x(i,j)  shipment quantities in cases
       z       total transportation costs in thousands of dollars ;

  Positive Variable x ;

  Equations
       cost        define objective function
       supply(i)   observe supply limit at plant i
       demand(j)   satisfy demand at market j ;

  cost ..        z  =e=  sum((i,j), c(i,j)*x(i,j)) ;

  supply(i) ..   sum(j, x(i,j))  =l=  a(i) ;

  demand(j) ..   sum(i, x(i,j))  =g=  b(j) ;

  Model transport /all/ ;

$onEchoV > sptest.gms
transport.savepoint=%1;

option lp=soplex,limrow=0,limcol=0;

x.up(i,j) = 300;

transport.number = 0;
Solve transport using lp minimizing z ;

option clear=z,clear=cost,clear=supply,clear=demand; x.l(i,j) = 0; x.m(i,j) = 0;

execute_loadpoint '%2';
transport.savepoint=0;

Solve transport using lp minimizing z ;

abort$(transport.solvestat <> %solveStat.normalCompletion% or
       transport.modelstat <> %modelStat.optimal% or
       transport.iterusd   <> 0    )  'something really wrong';
$offEcho
$batInclude sptest 1 'transport_p.gdx'
$batInclude sptest 2 'transport_p1.gdx'
$batInclude sptest 3 '%gams.scrdir%transport_p.gdx'
$batInclude sptest 4 '%gams.scrdir%transport_p1.gdx'

execute.checkErrorLevel 'rm "%gams.scrdir%transport_p.gdx"';
execute.checkErrorLevel 'rm "%gams.scrdir%transport_p1.gdx"';