Description

This test ensures that asynchronous solves generate savepoints
as well.

Contributor: Lutz Westermann, June 2021

Small Model of Type : GAMS

Category : GAMS Test library

Main file : savep2.gms

$title Test savepoint with async solves (SAVEP2,SEQ=864)

$onText
This test ensures that asynchronous solves generate savepoints
as well.

Contributor: Lutz Westermann, June 2021
$offText


$onEchoV > trans.gms
Set
   i 'canning plants' / seattle,  san-diego /
   j 'markets'        / new-york, chicago, topeka /;

Parameter
   a(i) 'capacity of plant i in cases'
        / seattle    350
          san-diego  600 /

   b(j) 'demand at market j in cases'
        / new-york   325
          chicago    300
          topeka     275 /;

Table d(i,j) 'distance in thousands of miles'
              new-york  chicago  topeka
   seattle         2.5      1.7     1.8
   san-diego       2.5      1.8     1.4;

Scalar f 'freight in dollars per case per thousand miles' / 90 /;

Parameter c(i,j) 'transport cost in thousands of dollars per case';
c(i,j) = f*d(i,j)/1000;

Variable
   x(i,j) 'shipment quantities in cases'
   z      'total transportation costs in thousands of dollars';

Positive Variable x;

Equation
   cost      'define objective function'
   supply(i) 'observe supply limit at plant i'
   demand(j) 'satisfy demand at market j';

cost..      z =e= sum((i,j), c(i,j)*x(i,j));

supply(i).. sum(j, x(i,j)) =l= a(i);

demand(j).. sum(i, x(i,j)) =g= b(j);

Model transport%gams.solveLink% / all /;

solve transport%gams.solveLink% using lp minimizing z;
x.lo(i,j) = 100;
solve transport%gams.solveLink% using lp minimizing z;
$offEcho

$call.checkErrorLevel gams trans.gms sl=4 savePoint=1 lo=%gams.lo%
$call.checkErrorLevel gams trans.gms sl=5 savePoint=1 lo=%gams.lo%
$call.checkErrorLevel gams trans.gms sl=7 savePoint=1 lo=%gams.lo%

$call.checkErrorLevel gdxdiff transport4_p.gdx transport5_p.gdx > %system.nullfile%
$call.checkErrorLevel gdxdiff transport7_p.gdx transport5_p.gdx > %system.nullfile%

$call.checkErrorLevel gams trans.gms sl=4 savePoint=2 lo=%gams.lo%
$call.checkErrorLevel gams trans.gms sl=5 savePoint=2 lo=%gams.lo%
$call.checkErrorLevel gams trans.gms sl=7 savePoint=2 lo=%gams.lo%

$call.checkErrorLevel gdxdiff transport4_p1.gdx transport5_p1.gdx > %system.nullfile%
$call.checkErrorLevel gdxdiff transport7_p1.gdx transport5_p1.gdx > %system.nullfile%
$call.checkErrorLevel gdxdiff transport4_p2.gdx transport5_p2.gdx > %system.nullfile%
$call.checkErrorLevel gdxdiff transport7_p2.gdx transport5_p2.gdx > %system.nullfile%